Attempt to hide console using Command line, Run, Exec and Pipe in VBScript

Question

I'm using Zbarimg which (I believe) outputs its data to STDOUT. So at present, a cmd string within a VBScript executes the command and stores it in a variable, thus:

xml_data=objShell.Exec("C:\MobiEvent\Zbar\bin\zbarimg -D -q --xml C:\MobiEvent\AllPics\*.jpg").stdout.readall

(For the uninitiated, -D stops it displaying an image of the barcode it reads from image, and -q keeps things quiet so only the XML data is output) That all works well with all the data of AllPics being stored in xml_data. Problem is, as ever, the console pops up a window that stays open whilst the script processes. And with 200+ photos, it stays open a while

The alternative is to use the Run command, and tag ",0,False" onto the end ... but then of course, the StdOut output is not picked up for post processing!

I'm wondering if it could be possible to combine the two using a pipe, my THEORETICAL syntax being ...

objShell.Run("C:\MobiEvent\Zbar\bin\zbarimg -D -q --xml C:\MobiEvent\AllPics\*.jpg"|to other script),0,True

** Not even sure if the program would do that as it may read the pipe as part of the directory path

Which then beggars the next question. If it =is= possible to pipe out the STDOUT, how do I read that piped output back into a second VBScript program? (All I need to do is get the output of the program to print out to a file so that I can post process by reading in again and splitting it into component parts to derive the photo filename and the QR value)

I know this "Run=hide window / Exec=cannot hide" debate has raged for a while. Just wondered if the above MIGHT prove an alternative option.

Answer 1

6 years late to this answer, but VBScript can execute a command and store the output without relying on pipes or writing the output to temporary files.

This function executes a command (without displaying a console window) and returns the output as an array:

Function Execute_Command(sCmd)

    Dim i : i = 0

    Dim oExec : Set oExec = CreateObject("WScript.Shell").Exec(sCmd)
    Do Until oExec.StdOut.AtEndOfStream
        ReDim Preserve sOutput(i)
        sOutput(i) = oExec.StdOut.ReadLine()
        i = i + 1
    Loop
    Set oExec = Nothing

    ' If no output produced, create an empty array
    If i = 0 Then Redim sOutput(0)

    Execute_Command = sOutput
    
End Function

Two notes:

1. Whilst you could concatenate each line into a string and then return that, you'll find that dealing with large amounts of output has a really heavy performance impact (approximately 10x slower!)
2. Whilst there is no need to create an empty array if there is no output, it makes life easier by ensuring that the function always returns an array.

To use, try something like this:

Dim sLine
For Each sLine In Execute_Command("ping -n 2 superuser.com")
    WScript.Echo "=> " & sLine
Next

Which generates the following output:

C:\Users\Richard\Desktop>cscript /nologo exec.vbs
=>
=> Pinging superuser.com [151.101.65.69] with 32 bytes of data:
=> Reply from 151.101.65.69: bytes=32 time=12ms TTL=60
=> Reply from 151.101.65.69: bytes=32 time=13ms TTL=60
=>
=> Ping statistics for 151.101.65.69:
=>     Packets: Sent = 2, Received = 2, Lost = 0 (0% loss),
=> Approximate round trip times in milli-seconds:
=>     Minimum = 12ms, Maximum = 13ms, Average = 12ms

Answer 2

I've no idea about your specific piece of software, but you can pipe and you can redirect in vbScript using the .Run command. For example:

' demonstrate piping and redirecting output with .Run
Set objShell = WScript.CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")
strTemp=objShell.ExpandEnvironmentStrings("%TEMP%") & "\"
strCmd=objShell.ExpandEnvironmentStrings("%comspec%") & " /C"

' here is the action
objShell.Run strCmd & "echo hello and welcome|findstr /N welcome >" & strTemp & "test.txt",0, True

' read the file back to show it was created successfully
Set file = objFSO.OpenTextFile(strTemp & "test.txt", 1)
strTaskText = file.ReadAll
strTaskText=Left(strTaskText,Len(strTaskText)-2) ' remove trailing vbCrLf
file.Close

MsgBox "The output was:" & vbcrlf & strTaskText